/*
hundeblink
@autor: Marcus Guin Kluetmann
Für die Funktion des Buttons wurde das "Debounce" Beispiel
http://www.arduino.cc/en/Tutorial/Debounce
created 21 November 2006
by David A. Mellis
modified 30 Aug 2011
by Limor Fried
modified 28 Dec 2012
by Mike Walters
genutzt und angepasst.
Die Methode goToSleep wurde hier entliehen
http://www.arduino-hausautomation.de/2014/emils-ampel-attiny45-im-tiefschlaf/
*/
#include <avr/sleep.h>
#include <avr/interrupt.h>
#define BODS 7 //BOD Sleep bit in MCUCR
#define BODSE 2 //BOD Sleep enable bit in MCUCR
uint8_t mcucr1, mcucr2;
int PWM1 = 0; // PWM LED
int PWM2 = 1; // PWM LED
int currentLED=0;
long lauflichtTimer;
int flashIntervall = 500; // Flash-Intervall
int flashdauer = 50;
int hell = 255; // Maximalhelligkeit der PWM LED
int dunkel = 2; // Minimalhelligkeit der PWM LED
int mittel = 5;// Mittlere Helligkeit nach dem Blitz für PWM LED
int buttonPin = 2;
int buttonState; // the current reading from the input pin
int lastButtonState = LOW; // the previous reading from the input pin
long lastDebounceTime = 0; // the last time the output pin was toggled
long debounceDelay = 250; // the debounce time; increase if the output flickers
int ledState = 0;
ISR(INT0_vect) {
}
void goToSleep(void) {
GIMSK |= _BV(INT0); //enable INT0
MCUCR &= ~(_BV(ISC01) | _BV(ISC00)); //INT0 on low level
ACSR |= _BV(ACD); //disable the analog comparator
ADCSRA &= ~_BV(ADEN); //disable ADC
set_sleep_mode(SLEEP_MODE_PWR_DOWN);
sleep_enable();
//turn off the brown-out detector.
//must have an ATtiny45 or ATtiny85 rev C or later for software to be able to disable the BOD.
//current while sleeping will be <0.5uA if BOD is disabled, <25uA if not.
cli();
mcucr1 = MCUCR | _BV(BODS) | _BV(BODSE); //turn off the brown-out detector
mcucr2 = mcucr1 & ~_BV(BODSE);
MCUCR = mcucr1;
MCUCR = mcucr2;
sei(); //ensure interrupts enabled so we can wake up again
sleep_cpu(); //go to sleep
cli(); //wake up here, disable interrupts
GIMSK = 0x00; //disable INT0
sleep_disable();
sei(); //enable interrupts again (but INT0 is disabled from above)
}
void setup() {
pinMode(buttonPin, INPUT_PULLUP); // interner PullUp Widerstand wird genutzt.
pinMode(PWM1, OUTPUT);
pinMode(PWM2, OUTPUT);
pinMode(3, OUTPUT);
pinMode(4, OUTPUT);
lauflichtTimer = millis();
digitalWrite(3, LOW);
digitalWrite(4, LOW);
}
void loop() {
// read the state of the switch into a local variable:
int reading = digitalRead(buttonPin);
// check to see if you just pressed the button
// (i.e. the input went from LOW to HIGH), and you've waited
// long enough since the last press to ignore any noise:
// If the switch changed, due to noise or pressing:
if (reading != lastButtonState) {
// reset the debouncing timer
lastDebounceTime = millis();
}
if ((millis() - lastDebounceTime) > debounceDelay) {
// whatever the reading is at, it's been there for longer
// than the debounce delay, so take it as the actual current state:
// if the button state has changed:
if (reading != buttonState) {
buttonState = reading;
// only toggle the LED if the new button state is HIGH
if (buttonState == HIGH) {
ledState++; // = !ledState;
//if(ledState>3) ledState=0;
//off(); // beim Statuswechsel werden alle LEDs ausgeschaltet.
}
}
}
// set the LED-Mode
if (ledState==1) lauflicht();
else if(ledState==2) dauerLicht();
else if(ledState==3) { off();goToSleep();ledState=1;lauflicht();}
// save the reading. Next time through the loop,
// it'll be the lastButtonState:
lastButtonState = reading;
}
// Beim Umschalten zwischen den Modi sollen die LED alle abgeschaltet werden.
void off(){
digitalWrite(PWM1, LOW);
digitalWrite(PWM2, LOW);
}
// Nur eine LED soll im Dauerbetrieb schwach leuchten
void dauerLicht(){
analogWrite(PWM2, mittel);
analogWrite(PWM1, mittel);
}
// Lässt die LEDs in der Reihenfolge, die im Array angegeben ist, für "flashdauer"
// mit der Intensität "hell" nacheinander aufleuchten.
// in der restlichen Zeit leuchten die LEDs mit der Intensität "dunkel"
void lauflicht() {
long time = millis();
int array[8] = {PWM1, PWM2};
int anzahlLEDinArray = 2; // hier die Anzahl der Array-Elemente eintragen
if(time-lauflichtTimer>currentLED*flashIntervall && time-lauflichtTimer < currentLED*flashIntervall+flashdauer){
analogWrite(array[currentLED], hell);}
if(time-lauflichtTimer>currentLED*flashIntervall+flashdauer && time-lauflichtTimer < (currentLED+1)*flashIntervall){
analogWrite(array[currentLED++], dunkel);}
if(time-lauflichtTimer>anzahlLEDinArray*flashIntervall){lauflichtTimer=millis();currentLED=0;}
}
